Raxen/build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id "com.github.johnrengelman.shadow" version "8.1.1"
    id "io.papermc.paperweight.userdev" version "1.5.4"
}

apply plugin: "java"
apply plugin: "io.papermc.paperweight.userdev"
apply plugin: "com.github.johnrengelman.shadow"

repositories {
    mavenLocal()
    maven {
        url = uri('https://jitpack.io')
    }
    maven {
        name = "PaperMc"
        url = uri('https://papermc.io/repo/repository/maven-public/')
    }
    maven {
        url = uri('https://oss.sonatype.org/content/groups/public/')
    }
    maven {
        name = 'CodeMC'
        url = 'https://repo.codemc.org/repository/maven-public/'
    }
    maven {
        url = uri('https://repo.dmulloy2.net/repository/public/')
    }
    maven {
        name = "EssentialsX"
        url = uri('https://repo.essentialsx.net/releases/')
    }
    maven {
        url = uri('https://s01.oss.sonatype.org/content/repositories/snapshots/')
    }
    maven {
        url = uri('https://repo.maven.apache.org/maven2/')
    }
    maven {
        name = "PlaceHolderApi"
        url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/'
    }
    maven {
        name = "Citizens"
        url = 'https://repo.citizensnpcs.co/'
    }
    maven {
        url = "https://repo.onarandombox.com/content/groups/public/"
    }
    maven {
        name = "Worldedit"
        url = 'https://maven.enginehub.org/repo/'
    }
    mavenCentral()
}

dependencies {
    // lombok stuff
    implementation 'org.projectlombok:lombok:1.18.26'
    annotationProcessor 'org.projectlombok:lombok:1.18.26'
    testCompileOnly 'org.projectlombok:lombok:1.18.26'

    implementation 'org.apache.httpcomponents:httpclient:4.5.13'
    implementation 'org.apache.httpcomponents:httpmime:4.5.13'

    // mongo stuff
    implementation 'org.mongodb:mongodb-driver-sync:4.9.1'
    implementation 'org.mongodb:bson:4.9.1'
    implementation 'org.mongodb:mongodb-driver-core:4.9.1'

    implementation 'redis.clients:jedis:4.3.1'

    compileOnly 'io.papermc.paper:paper-api:1.19.4-R0.1-SNAPSHOT'
    implementation 'de.tr7zw:item-nbt-api-plugin:2.11.2'
//    compileOnly 'de.tr7zw:item-nbt-api:2.11.2'
    compileOnly 'com.comphenix.protocol:ProtocolLib:5.0.0'
    compileOnly 'com.github.MilkBowl:VaultAPI:1.7.1'
    compileOnly 'net.essentialsx:EssentialsX:2.19.7'
    compileOnly 'com.sk89q.worldedit:worldedit-core:7.2.14'
    compileOnly 'com.sk89q.worldedit:worldedit-bukkit:7.2.14'
    compileOnly 'me.clip:placeholderapi:2.11.3'
    compileOnly('net.citizensnpcs:citizens-main:2.0.31-SNAPSHOT') {
        exclude group: '*', module: '*'
    }
    compileOnly 'com.onarandombox.multiversecore:Multiverse-Core:4.3.1'
    implementation 'com.github.decentsoftware-eu:decentholograms:2.8.1'
    paperweightDevelopmentBundle("io.papermc.paper:dev-bundle:1.19.4-R0.1-SNAPSHOT")
}

group = 'me.unurled'
version = '0.6.0'
description = 'Raxen'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
    options.release = 17
    options.compilerArgs += ["-Xlint:unchecked", "-Xlint:deprecation"]
}

tasks {
    assemble {
        dependsOn(reobfJar)
    }
    build {
        dependsOn(shadowJar)
    }
}

shadowJar {
    dependencies {
        include dependency('de.tr7zw:item-nbt-api-plugin:2.11.2')
        include dependency('de.tr7zw:item-nbt-api:2.11.2')
        include dependency('org.mongodb:mongodb-driver-sync:4.9.1')
        include dependency('org.mongodb:bson:4.9.1')
        include dependency('org.mongodb:mongodb-driver-core:4.9.1')
        include dependency('com.github.decentsoftware-eu:decentholograms:2.8.1')
        include dependency('org.apache.httpcomponents:httpclient:4.5.13')
        include dependency('org.apache.httpcomponents:httpmime:4.5.13')
        include dependency('redis.clients:jedis:4.3.1')
    }
    relocate("de.tr7zw", "me.unurled.libs.de.tr7zw")
    relocate("com.mongodb", 'me.unurled.libs.com.mongodb')
    relocate("org.bson", 'me.unurled.libs.org.bson')
    relocate('eu.decentsoftware', 'me.unurled.libs.eu.decentsoftware')
    relocate('org.apache', 'me.unurled.libs.org.apache')
    relocate('redis.clients', 'me.unurled.libs.redis.clients')
    processResources {
        expand version: project.version
    }
    minimize()
}

sourceSets {
    main {
        resources {
            srcDirs = ['src/main/resources']
        }
    }
}

processResources {
    exclude '**/*.schem'
}