plugins {
    `java-library`
    id("io.papermc.paperweight.userdev") version "1.5.11"
    id("com.github.johnrengelman.shadow") version "8.1.1"
}

group = "me.unurled.sacredrealms"
version = "0.1.0"
description = "The main SR plugin."

repositories {
    mavenCentral()
}

dependencies {
    paperweight.paperDevBundle("1.20.4-R0.1-SNAPSHOT")

    implementation("redis.clients:jedis:5.1.0")

    testCompileOnly("com.github.seeseemelk:MockBukkit-v1.20:3.74.0")
    testCompileOnly("org.junit.jupiter:junit-jupiter-api:5.10.1")
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(17))
}

tasks {
    assemble {
        dependsOn(reobfJar)
    }

    compileJava {
        options.encoding = Charsets.UTF_8.name()

        options.release.set(17)
    }
    javadoc {
        options.encoding = Charsets.UTF_8.name()
    }
    processResources {
        filteringCharset = Charsets.UTF_8.name()
        val props = mapOf(
            "name" to project.name,
            "version" to project.version,
            "description" to project.description,
            "apiVersion" to "1.20"
        )
        inputs.properties(props)
        filesMatching("paper-plugin.yml") {
            expand(props)
        }
    }
    shadowJar {
        archiveClassifier.set("")
        relocate("com.google", "libs.com.google")
        relocate("org.apache", "libs.org.apache")
        relocate("org.json", "libs.org.json")
        exclude("org.slf4j")
        relocate("redis", "libs.redis")
        minimize()
    }
}